home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Cream of the Crop 11
/
Cream of the Crop 11-1.iso
/
religion
/
calv1295.zip
/
CCSCRIPT.ZIP
/
CALVARY.ASP
next >
Wrap
Text File
|
1994-09-04
|
6KB
|
138 lines
; SHEPHERD.ASP
; The Shepherd's Flock Family BBS
; SYSOP: John Scudder
; 822 Masters Drive
; Oceanside, California 92057-6233
; BBS: 619-630-7437 or 7303
;**************************************************************************
;* This is an aspect script file written for ProComm Plus v2.01 to *
;* automate mail runs on The Shepherd's Flock Family BBS. It can be used *
;* for QWK-style Net-mail runs and should work equally well for the *
;* regular BBS user who just wants to do hands-off mail transfers. I am *
;* not a programmer by any stretch of the imagination. Please consult *
;* your Aspect Reference Manual if anything goes wrong. If that fails, *
;* I can be reached by using any one of the methodes listed below. If you *
;* find a way to imporve on this, feel free to do so. Be sure to upload *
;* your improved version to the Shepherd's Flock BBS so that others may *
;* enjoy it! May God bless you as you seek to be closer to Him! *
;* Jeffrey Haney --SYSOP, Saltshaker BBS (714) 850-1539 & (714)850-1372 *
;* InterNet: jeffrey_haney@saltshaker.win.net *
;* Snail Mail: Salt Shaker BBS *
;* 20068 Santa Ana Ave. #323 *
;* Santa Ana, CA 92707 *
;* I can also be reached on CalvaryNet and PhileoNet *
;**************************************************************************
; You will need to change these few entries below this line. After that,
; you shouldn't have to change anything. To run and compile this script,
; start PCPlus with the following command line: PCPLUS /fSHEPHERD.ASX
;**************************************************************************
DEFINE BBS_ENTRY "7" ;Change this to whatever Dialing
;Directory Entry you've set up
;Shepherd's Flock on.
DEFINE FULL_NAME "first last password" ;Change this to your own first
;name, last name, and password
DEFINE REPLIES "d:\upload\shepherd.REP" ;Change this to where your REP
;packets are stored.
DEFINE PACKET "d:\dnload\shepherd.QWK" ;Change this to where your QWK
;packets are stored. Be sure to
;use your default download dir.
DEFINE LOG_FILE "shepherd.LOG" ;No need to change this. This
;file is useful to help you find
;problems in your script.
;╓╥───────────────────────────────────────────────────────────────────────╥╖
;║║ This script should not require any changes below this line. All ║║
;║║ variables are defined in the above statements. Please edit these ║║
;║║ for your particular setup! ║║
;╙╨───────────────────────────────────────────────────────────────────────╨╜
;---------------------------------------------------------------------------
PROC MAIN
SET MODEM MAXDIAL 100 ;QUIT IF NO ANSWER OR BUSY AFTER
;100 TRIES
DELETE LOG_FILE ;Delete previous log entry
LOG OPEN LOG_FILE ;Open new logfile
FINDFIRST PACKET ;Deletes old .QWK packet, in case
IF FOUND ;you didn't already have that taken
DELETE PACKET ;care of.....
ENDIF
SET ZMODEM AUTODLOAD ON ;Sets the Auto-Download function on
DIAL BBS_ENTRY ;Dials entry from dialing directory
IF NOT CONNECTED ;If it doesn't connect, then it will
HANGUP ;hang up and quit.
QUIT
ENDIF
WHEN 0 "continue? " Transmit "^M" ;This will transmit a carraige return
;to get you through all those "Enter=
;Continue" prompts.
WHEN 1 "More? " Transmit "N^M" ;This will get you through all of the
;"more?" prompts
WAITFOR "ter)=English? " 20 ;This gets you by the Language prompt
Transmit "^M"
WAITFOR "(ENTER = NO)^M^J? " 20
TRANSMIT "N Q NS^M" ;Selects"N^M" for no graphics and
;speed you through a lot of the welcome
;screens.
WAITFOR "eal First Name? " 20 ; wait for first name prompt
IF NOT WAITFOR
TRANSMIT "^M"
ENDIF
TRANSMIT FULL_NAME ;Send your FULL name and password
TRANSMIT "^M^M"
WAITFOR " Board Command? " 30
TRANSMIT "MAIL^M" ;Open the Hub door
WAITFOR "m-Mail Command? " ;Wait for the command prompt
FINDFIRST REPLIES ;This section will look to see
IF FOUND ;if a .REP files exists as defined
TRANSMIT "U^M" ;above. If so, then the UPload
PAUSE 1 ;commands are executed. If not,
SENDFILE ZMODEM REPLIES ;take you to the download process.
ENDIF
WAITFOR "m-Mail Command? " ;Starts download process.
TRANSMIT "D^M"
WAITFOR "es (Enter)=Yes? " 35 ;Confirms that you want to receive
IF NOT WAITFOR ;messages. If no messages are found,
TRANSMIT "G^M" ;script will hang up and quit.
PAUSE 30
HANGUP
QUIT
ENDIF
TRANSMIT "^M" ;If messages are found, it will start
;the download process.
WAITFOR "m-Mail Command? " ;Sends the Goodbye command to log off
TRANSMIT "G^M"
PAUSE 30
QUIT ;& then quit Procomm.
ENDPROC